13.1 Hoeveel zorgverleners in loondienst zijn er ingestroomd?

Concepten

• Arbeidsovereenkomst
• Onverplaatsbaar artefact
• Vestiging
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.1
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ("Totaal organisatie" AS ?Indeling)
13    (SUM(?noemer_waarde) AS ?Aantal_PIL_met_zorgfunctie)
14    (SUM(?teller_waarde) AS ?Aantal_ingestroomde_PIL_met_zorgfunctie)
15    (IF(?Aantal_PIL_met_zorgfunctie = 0, "Ongedefinieerd", 100*(?Aantal_ingestroomde_PIL_met_zorgfunctie/?Aantal_PIL_met_zorgfunctie)) AS ?Percentage_zorggerelateerde_instroom_tov_totaal_zorggerelateerd)
16{
17    SELECT
18		?werknemer
19        (IF (MAX(?op_peildatum) = 1, 1, 0) AS ?noemer_waarde)
20        (IF (MAX(?op_peildatum) = 1 && MAX(?op_peildatum_eerder) = 0, 1, 0) AS ?teller_waarde)
21    {
22        # BIND(xsd:date("2024-08-01") AS ?peildatum)
23   	    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
24        BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
25
26        #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
27        ?overeenkomst
28            a onz-pers:ArbeidsOvereenkomst ;
29            onz-pers:heeftOpdrachtnemer ?werknemer ;
30            onz-g:hasPart ?overeenkomst_afspraak .
31        ?overeenkomst_afspraak
32            a onz-pers:WerkOvereenkomstAfspraak ;
33            onz-g:isAbout ?functie ;
34            onz-g:isAbout ?locatie ;
35            onz-g:startDatum ?start_afspraak .
36        ?functie 
37            a onz-pers:ZorgverlenerFunctie .
38        OPTIONAL {
39            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
40        }
41
42        ?locatie 
43            a onz-g:StationaryArtifact ;
44        	onz-g:partOf* ?vestiging_uri .
45        ?vestiging_uri a onz-org:Vestiging ;
46            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
47        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
48        ?pc_gebied 
49            onz-g:identifiedBy ?postcode ;
50            onz-g:partOf+ ?zk_regio .
51        ?zk_regio a onz-org:ZorgkantoorRegio .
52        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
53
54        BIND(IF(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum)
55        BIND(IF(?start_afspraak <= ?peildatum_eerder && ((?eind_afspraak >= ?peildatum_eerder) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum_eerder)
56    }
57    GROUP BY ?werknemer
58}